Re: Verifier la presence d'un mot dans tous les champs

Dans le message <tu01tv$21rv$1@cabale.usenet-fr.net>, Olivier Miakinen a écrit le 4 mars 2023 à 19 h 16 :

Maintenant il te reste à ajouter un test au début pour éviter
que "1,5" soit considéré comme une syntaxe valide sur un Mac en français
alors qu'il serait rejeté comme invalide en anglais.

Avec, en plus, une petite correction par rapport à la version
précédente :
=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=
global decimalSeparator

set decimalSeparator to character 2 of (1 / 2 as string)
set {valid_list, invalid_list} to {{""}, {""}}
set numList to {"0", "1,5", "+1.5", "1e+99", "-19E-7", "1.7e003", ".3", "1.2.3", "", "1E3.4", "--1", "e+99", ".", "+1e"}

repeat with k in numList
  if (k as string) = "" then
    set invalid_list to invalid_list & ""
  else if decimalSeparator is in k then
    set invalid_list to invalid_list & k
  else
    try
      set conv_num to (replace(k as string)) as number
      set valid_list to valid_list & k
      -- set conv_num to conv_num as number
    on error
      set invalid_list to invalid_list & k
    end try
  end if
end repeat
set text item delimiters to return & tab
display alert "Les éléments valides sont :" & (valid_list as text) & return & return & "Les éléments invalides sont :" & (invalid_list as text)

on replace(str)
  set text item delimiters to "."
  set list1 to every text item of str
  set text item delimiters to decimalSeparator
  set newStr to ("" & list1) as text
  set text item delimiters to ""
  return newStr
end replace
=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=

Résultat :
=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=
Les éléments valides sont :
  0
  +1.5
  1e+99
  -19E-7
  1.7e003
  .3

Les éléments invalides sont :
  1,5
  1.2.3
 
  1E3.4
  --1
  e+99
  .
  +1e"
=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=+=
--
🇺🇦 Michel Vauquois - <http://michelvauquois.fr> 🇺🇦
L'amour est comme un arbre, il pousse de lui-même, jette profondément ses
racines dans tout notre être et continue de verdoyer sur un cœur en ruine.