Re: Comment passer SignAuPif à la vitesse supérieure ?

"Benoît L." <benoit@com.invalid> wrote:

Si ça ne me plaît pas et j'en veux une autre je fais quoi ?

Je reprends : le script, au lieu de vous présenter le résultat suite à un "display
dialog", ouvre la fenêtre du presse-papiers pour vous montrer le résultat, par exemple
pendant 6 s, puis reprend la main pour vous demander si ça vous convient.
Si ça vous convient, le script s'arrête en refermant la fenêtre du PP mais sans vider bien
sûr celui-ci.
Si ça ne vous convient pas, le script se relance et vous fait une autre proposition et
ceci, autant de fois que nécessaire : jusqu'à satisfaction de l'intéressé !

Le schéma du script ne change donc en rien par rapport au script initial : la seule chose
qui change est la présentation du résultat.

Si je veux utiliser ou non les « --  » je fais comment ?

C'est une broutille.
Éventuellement, si vous le souhaitez, on propose, une fois que vous avez indiqué au script
que le résultat vous plaisait, de garder ou non le délimiteur de signature : vous
choisissez à ce moment là.
Ce "problème" est tout à fait anecdotique mais je l'ai inclus ci-dessous.
Bien entendi, si vous choisissez d'éliminer le « --  », c'est le nouveai résultat qui est
copié dans le presspapiers.

Essayez ceci (j'ai commenté les différentes instructions) en supprimant dans le script
initial toute la partie qui commence par :
repeat
et en la remplaçant par :
**************************************************************************
repeat
        -- choix de la signature
        set SignatureString to some item of theSignatureList as text
        -- remplacement de ¬ par un saut de ligne
        set AppleScript's text item delimiters to "¬"
        set tempSig to every text item of SignatureString
        set AppleScript's text item delimiters to return
        set finalSig to every text item of tempSig as text
        -- placement de la signature dans le PP
        set the clipboard to finalSig
        -- affichage du PP pendant 6 s
        show_PP()
        delay 6
        -- savoir si la signature convient
        tell application "Script Editor" to activate
        delay 0.2
        -- set dialogsign to "Signature copiée :" & return & finalSig
        set theDialog to (display dialog ¬
                "Cela vous convient-il ?" with title ("Tirage au sort de signature") ¬
                buttons {"Non", "Oui"} default button "Oui")
        set BUTTON_Returned to button returned of theDialog
        -- si la signature convient alors arrêter ce script et fermer ¬
        -- la fenêtre PP
        if BUTTON_Returned is "Oui" then
                tell application "Finder"
                        activate
                        tell application "System Events" to keystroke "w" using ¬
                                command down
                end tell
                exit repeat
        end if
        -- si la signature ne convient pas, le script se relance
end repeat

tell application "Script Editor" to activate
set choix_delimiteur to button returned of (display dialog ¬
        "Voulez-vous conserver le délimiteur de signature ?" ¬
with title ("Délimiteur de signature") ¬
        buttons {"Non", "Oui"} default button "Oui")
if choix_delimiteur is "Non" then
        set AppleScript's text item delimiters to return
        set resultat to the clipboard as text
        set no_del to text items 2 thru -1 of resultat
        set the clipboard to no_del as text
end if

set AppleScript's text item delimiters to " "

-- handler pour afficher le contenu du PP
on show_PP()
        tell application "Finder"
                tell application "System Events"
                        tell menu item "Afficher le presse-papiers" of ¬
                                menu "Édition" of menu bar item "Édition" of ¬
                                menu bar 1 of application process "Finder"
                                click
                        end tell
                end tell
                activate
        end tell
end show_PP

**************************************************************************

Il suffit juste de régler auparavant la taille de la fenêtre du presse-papiers.
Voici un résultat obtenu après 3 propositions du script :
--
CF : les rouleaux à l'intérieur sont plus larges, j'imagine que ça doit
     améliorer le contact avec la boule.
JMG: C'est vrai que c'est vachement plus agréable...
-+- JMG in Guide du Macounet Pervers : Bien nettoyer ses boules -+-