Re: Avoid treating the stack as an array [Re: "Back & Forth" is back!]

On Sat, 14 Sep 2024 17:41:23 +0000, Ahmed wrote:

On Sat, 14 Sep 2024 17:13:51 +0000, Ahmed wrote:
>

utime 0.1e neg_big utime d- dnegate d.
with locals:    about 19 ms
without locals: about 18 ms
>
Ahmed

Oops.
>
Please read micro seconds (us) instead of milli seconds (ms).
>
with locals:    about 19 us
without locals: about 18 us

That can't be correct.
In iForth I used dfloats instead of floats
( 4.9ns instead of 7.3ns).
Using structs is not a great idea in this case.
anew -testlocals
: tri_mf:  ( f: a b c )
     create frot df, fswap df, df,
     does> ( F: x -- y )
            ( ad_a)           ( f: x)
       dup fdup        ( ad_a ad_a)      ( f: x x)
       df@             ( ad_a)           ( f: x x a)
       f>=             ( ad_a -1|0)      ( f: x)
       over dfloat+    ( ad_a -1|0 ad_b) ( f: x)
       fdup df@        ( ad_a -1|0)      ( f: x x b)
       f< and if       ( ad_a)           ( f: x)
         dup df@ f-    ( ad_a)           ( f: x-a)
         dup df@       ( ad_a)           ( f: x-a a)
         dfloat+       ( ad_b)           ( f: x-a a)
         f@ fswap f-                     ( f: x-a b-a)
         f/                              ( f: [x-a]/[b-a])
         exit
       then
       dfloat+         ( ad_b)           ( f: x)
       dup fdup        ( ad_b ad_b)      ( f: x x)
       df@             ( ad_b)           ( f: x x b)
       f>=             ( ad_b -1|0)      ( f: x)
       over dfloat+    ( ad_b -1|0 ad_c) ( f: x)
       fdup df@        ( ad_b -1|0)      ( f: x x c)
       f< and if       ( ad_b)           ( f: x)
         dup dfloat+ df@ ( ad_b)         ( f: x c)
         f-            ( ad_b)           ( f: x-c)
         dup dfloat+   ( ad_b ad_c)      ( f: x-c)
         swap df@ df@ f-                 ( f: x-c b-c)
         f/                              ( f: [x-c]/[b-c])
         exit
       then
       drop fdrop
       0e
;
-1e309    -1e     0e         tri_mf: nol_neg_big
: (tri_mf) ( f: x a b c -- mv)
FLOCALS| c b a x |
x a f>= x b f< and if x a f- b a f- f/ exit then
x b f>= x c f< and if c x f- c b f- f/ exit then
0e ;
: loc_neg_big -1e309 -1e   0e   (tri_mf) ;
: .timing MS? S>F 1e-3 F*  1e7 F/ F.N2 ." s/call." ;
: tnb CR ." \ no locals: " TIMER-RESET #10000000  ( 1e7 times )
   0 DO  -10e   nol_neg_big FDROP  LOOP .timing
CR ." \    locals: " TIMER-RESET #10000000  ( 1e7 times )
   0 DO  -10e   loc_neg_big FDROP  LOOP .timing ;
FORTH> tnb
\ no locals: 4.9ns/call.
\    locals: 21.3ns/call. ok
-marcel