Re: Avoid treating the stack as an array [Re: "Back & Forth" is back!]

This unearthed a "bug": -1e309 does not fit in a dfloat,
it prints as -Inf.
anew -testlocals
0e dfvalue a PRIVATE
0e dfvalue b PRIVATE
0e dfvalue c PRIVATE
( based on dxf's outline )
: gv_tri_mf ( f: x a b c -- mv )
  to c  to b  to a
  fdup a f>=  fdup b f< and if   a f-        b a f- f/  exit  endif
  fdup b f>=  fdup c f< and if   c fswap f-  c b f- f/  exit  endif
  0e ;
: gv_neg_big  -1e308 ( ! )  -1e 0e gv_tri_mf ;
: tri_mf:  ( f: a b c )
     create frot df, fswap df, df,
     does> ( F: x -- y )
            ( ad_a)           ( f: x)
       dup fdup        ( ad_a ad_a)      ( f: x x)
       df@             ( ad_a)           ( f: x x a)
       f>=             ( ad_a -1|0)      ( f: x)
       over dfloat+    ( ad_a -1|0 ad_b) ( f: x)
       fdup df@        ( ad_a -1|0)      ( f: x x b)
       f< and if       ( ad_a)           ( f: x)
         dup df@ f-    ( ad_a)           ( f: x-a)
         dup df@       ( ad_a)           ( f: x-a a)
         dfloat+       ( ad_b)           ( f: x-a a)
         f@ fswap f-                     ( f: x-a b-a)
         f/                              ( f: [x-a]/[b-a])
         exit
       then
       dfloat+         ( ad_b)           ( f: x)
       dup fdup        ( ad_b ad_b)      ( f: x x)
       df@             ( ad_b)           ( f: x x b)
       f>=             ( ad_b -1|0)      ( f: x)
       over dfloat+    ( ad_b -1|0 ad_c) ( f: x)
       fdup df@        ( ad_b -1|0)      ( f: x x c)
       f< and if       ( ad_b)           ( f: x)
         dup dfloat+ df@ ( ad_b)         ( f: x c)
         f-            ( ad_b)           ( f: x-c)
         dup dfloat+   ( ad_b ad_c)      ( f: x-c)
         swap df@ df@ f-                 ( f: x-c b-c)
         f/                              ( f: [x-c]/[b-c])
         exit
       then
       drop fdrop
       0e
;
-1e309    -1e     0e         tri_mf: nol_neg_big
: (tri_mf) ( f: x a b c -- mv)
FLOCALS| c b a x |
x a f>= x b f< and if x a f- b a f- f/ exit then
x b f>= x c f< and if c x f- c b f- f/ exit then
0e ;
: loc_neg_big -1e309 -1e   0e   (tri_mf) ;
: .timing MS? S>F 1e-3 F*  1e7 F/ F.N2 ." s/call." ;
: tnb CR ." \ no locals: " TIMER-RESET #10000000  ( 1e7 times )
   0 DO  -10e   nol_neg_big FDROP  LOOP .timing
CR ." \    locals: " TIMER-RESET #10000000  ( 1e7 times )
   0 DO  -10e   loc_neg_big FDROP  LOOP .timing
CR ." \   globals: " TIMER-RESET #10000000  ( 1e7 times )
   0 DO  -10e   gv_neg_big  FDROP  LOOP .timing ;
FORTH> tnb
\ no locals: 4.9ns/call.
\    locals: 21.4ns/call.
\   globals: 6.2ns/call. ok
Surprisingly, there is hardly a difference between no locals and
global variables. The stack juggling in tri_mf: is merely an
intellectual exercise (in this case).
-marcel