Re: Avoid treating the stack as an array [Re: "Back & Forth" is back!]

Hi,
Here is another version (no locals (flocals), no fvalues, no
fvariables).
I tried to factor the code little bit.
It gives about 81 ns/call (gforth under wsl).
: x_a_b ( f: x a b c -- x a b c x a b)
   3 fpick 3 fpick 3 fpick
;
: x_b_c ( f: x a b c -- x a b c x b c)
   3 fpick 2 fpick 2 fpick
;
: fwithin ( f: x r s --) ( -- -1|0)
  frot ftuck
   f>= f< and
;
: mv ( f: x r s -- mv)
   fover f-      ( f: x r s-r)
   frot frot f-  ( f: s-r x-r)
   fswap f/
;
: 4fdrop fdrop fdrop fdrop fdrop ;
: tri_mf ( f: x a b c -- mv)
   x_a_b fwithin if fdrop            mv exit then
   x_b_c fwithin if frot fdrop fswap mv exit then
   4fdrop 0e
;
: neg_big -1e308  -1e    0e    tri_mf ;
: zero    -1e      0e    1e    tri_mf ;
: pos_big  0e      1e    1e308 tri_mf ;
: fuzzify ( f: x)
    fdup neg_big cr f.
    fdup zero    cr f.
         pos_big cr f.
;
: go 0 do -0.1e neg_big fdrop loop ;
utime 100000000 go utime d>f d>f f- 1e8 f/ f. 0.08081444  ok
utime 100000000 go utime d>f d>f f- 1e8 f/ f. 0.0806888  ok
utime 100000000 go utime d>f d>f f- 1e8 f/ f. 0.08064737  ok
utime 100000000 go utime d>f d>f f- 1e8 f/ f. 0.08140588  ok
utime 100000000 go utime d>f d>f f- 1e8 f/ f. 0.08233884  ok
Ahmed